random-distributions/f-distribution.ss
;;; PLT Scheme Science Collection
;;; random-distributions/f-distribution.ss
;;; Copyright (c) 2004 M. Douglas Williams
;;;
;;; This library is free software; you can redistribute it and/or
;;; modify it under the terms of the GNU Lesser General Public
;;; License as published by the Free Software Foundation; either
;;; version 2.1 of the License, or (at your option) any later version.
;;;
;;; This library is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; Lesser General Public License for more details.
;;;
;;; You should have received a copy of the GNU Lesser General Public
;;; License along with this library; if not, write to the Free
;;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
;;; 02111-1307 USA.
;;;
;;; -------------------------------------------------------------------
;;;
;;; This module implements the f-distribution.  It is based on the
;;; Random Number Distributions in the GNU Scientific Library.
;;;
;;; Version  Date      Description
;;; 1.0.0    09/28/04  Marked as ready for Release 1.0.  Added
;;;                    contracts for functions.  (Doug Williams)

(module f-distribution mzscheme
  
  (require (lib "contract.ss"))
  
  (provide/contract
   (random-f-distribution
    (case-> (-> random-source? real? real? (>=/c 0.0))
            (-> real? real? (>=/c 0.0))))
   (f-distribution-pdf
    (-> real? real? real? (>=/c 0.0))))
  
  (require "../random-source.ss")
  (require "../special-functions/gamma.ss")
  (require "gamma.ss")
  
  ;; random-f-distribution: random-source x real x real -> real
  ;; random-f-distribution: real x real -> real
  ;;
  ;; This function returns a random variate from the F-distribution
  ;; with degrees of freedom nu1 and nu2.
  (define random-f-distribution
    (case-lambda
      ((r nu1 nu2)
       (let ((y1 (random-gamma r (/ nu1 2.0) 2.0))
             (y2 (random-gamma r (/ nu2 2.0) 2.0)))
         (/ (* y1 nu2) (* y2 nu1))))
      ((nu1 nu2)
       (random-f-distribution (current-random-source) nu1 nu2))))
  
  ;; f-distribution-pdf: real x real x real -> real
  ;;
  ;; This function computes the probability density p(x) at x of an
  ;; f-distribution with degrees of freedom nu1 and nu2.
  (define (f-distribution-pdf x nu1 nu2)
    (if (< x 0.0)
        0.0
        (let ((lglg (+ (* (/ nu1 2.0) (log nu1))
                       (* (/ nu2 2.0) (log nu2))))
              (lg12 (lngamma (/ (+ nu1 nu2) 2.0)))
              (lg1 (lngamma (/ nu1 2.0)))
              (lg2 (lngamma (/ nu2 2.0))))
          (* (exp (+ lglg lg12 (- lg1) (- lg2)))
             (expt x (- (/ nu1 2.0) 1.0))
             (expt (+ nu2 (* nu1 x)) (- (/ (- nu1) 2.0) (/ nu2 2.0)))))))
  
)