;;; PLT Scheme Science Collection
;;; random-distributions/bivariate-gaussian.ss
;;; Copyright (c) 2004 M. Douglas Williams
;;;
;;; This library is free software; you can redistribute it and/or
;;; modify it under the terms of the GNU Lesser General Public
;;; License as published by the Free Software Foundation; either
;;; version 2.1 of the License, or (at your option) any later version.
;;;
;;; This library is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; Lesser General Public License for more details.
;;;
;;; You should have received a copy of the GNU Lesser General Public
;;; License along with this library; if not, write to the Free
;;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
;;; 02111-1307 USA.
;;;
;;; -------------------------------------------------------------------
;;;
;;; This module implements the bivariate gaussian distribution.  It
;;; is based on the Random Number Distributions in the GNU Scientific
;;; Library.
;;;
;;; Version  Date      Description
;;; 1.0.0    09/28/04  Marked as ready for Release 1.0.  Added
;;;                    contracts for functions.  (Doug Williams)

(module bivariate-gaussian mzscheme
  
  (require (lib "contract.ss"))
  
  (provide/contract
   (random-bivariate-gaussian
    (case-> (-> random-source? (>=/c 0.0) (>=/c 0.0) (real-in -1.0 1.0)
                (values real? real?))
            (-> (>=/c 0.0) (>=/c 0.0) (real-in -1.0 1.0)
                (values real? real?))))
   (bivariate-gaussian-pdf
    (-> real? real? (>=/c 0.0) (>=/c 0.0) (real-in -1.0 1.0) real?)))
  
  (require "../math.ss")
  (require "../random-source.ss")
  
  ;; random-bivariate-gaussian: random-source x real x real x real ->
  ;;                              real x real
  ;; random-bivariate-gaussian: real x real x real -> real x real
  ;; This function generates a pair of correlated gaussian variates,
  ;;; with mean zero, correlation coefficient rho, and standard
  ;; deviations sigma-x and sigma-y in the x and y directions.  The
  ;; bivariate gaussian distribution probability distribution is
  ;;
  ;;   p(x,y) dxdy = (1/(2 pi sigma_x sigma_y sqrt(r)))
  ;;                   exp(- (x^2 + y^2 - 2 r x y)/(2c)) dxdy
  ;;
  ;; The correlation coefficient rho should lie between 1 and -1.
  (define random-bivariate-gaussian
    (case-lambda
      ((r sigma-x sigma-y rho)
       (let ((u 0.0)
             (v 0.0)
             (r2 0.0)
             (scale 0.0))
         (let loop ()
           (set! u (+ -1.0 (* 2.0 (random-uniform r))))
           (set! v (+ -1.0 (* 2.0 (random-uniform r))))
           (set! r2 (+ (* u u) (* v v)))
           (if (or (> r2 1.0)
                   (= r2 0.0))
               (loop)))
         (set! scale (sqrt (/ (* -2.0 (log r2)) r2)))
         (values
          (* sigma-x u scale)
          (* sigma-y (+ (* rho u) (* (sqrt (- 1.0 (* rho rho))) v)) scale))))
      ((sigma-x sigma-y rho)
       (random-bivariate-gaussian (current-random-source) sigma-x sigma-y rho))))
  
  ;; Bivariate-gaussian-pdf: real x real x real x real x real -> real
  (define (bivariate-gaussian-pdf x y sigma-x sigma-y rho)
    (let ((u (/ x sigma-x))
          (v (/ y sigma-y))
          (c (- 1.0 (* rho rho))))
      (* (/ 1.0 (* 2.0 pi sigma-x sigma-y (sqrt c)))
         (exp (/ (- (+ (* u u) (* -2.0 rho u v) (* v v))) (* 2.0 c))))))
  
)