random-distributions/triangular.ss
#lang scheme/base
;;; PLT Scheme Science Collection
;;; random-distributions/triangular.ss; version 0.9.0
;;; Copyright (c) 2004-2008 M. Douglas Williams
;;;
;;; This library is free software; you can redistribute it and/or
;;; modify it under the terms of the GNU Lesser General Public
;;; License as published by the Free Software Foundation; either
;;; version 2.1 of the License, or (at your option) any later version.
;;;
;;; This library is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; Lesser General Public License for more details.
;;;
;;; You should have received a copy of the GNU Lesser General Public
;;; License along with this library; if not, write to the Free
;;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
;;; 02111-1307 USA.
;;;
;;; -------------------------------------------------------------------
;;;
;;; This code implements a triangular distribution.
;;;
;;; Version  Date      Description
;;; 0.9.0    08/06/04  This is the initial release of the triangular
;;;                    distribution routines. (Doug Williams)
;;; 1.0.0    09/28/04  Marked as ready for Release 1.0.  Added
;;;                    contracts for functions.  (Doug Williams)
;;; 2.0.0    11/19/07  Added unchecked versions of functions and
;;;                    getting ready for PLT Scheme 4.0 (Doug Williams)
;;; 3.0.0    06/09/05  Changes required for V4.0.  (Doug Williams)

(require (lib "contract.ss"))

(provide
 (rename-out (random-triangular unchecked-random-triangular)
             (triangular-pdf unchecked-triangular-pdf)
             (triangular-cdf unchecked-triangular-cdf)))

(provide/contract
 (random-triangular
  (case-> (->r ((r random-source?)
                (a real?)
                (b (>/c a))
                (c (and/c (>=/c a)
                          (<=/c b))))
               real?)
          (->r ((a real?)
                (b (>/c a))
                (c (and/c (>=/c a)
                          (<=/c b))))
               real?)))
 (triangular-pdf
  (->r ((x real?)
        (a real?)
        (b (>/c a))
        (c (and/c (>=/c a)
                  (<=/c b))))
       (>=/c 0.0)))
 (triangular-cdf
  (->r ((x real?)
        (a real?)
        (b (>/c a))
        (c (and/c (>=/c a)
                  (<=/c b))))
       (real-in 0.0 1.0))))

(require "../random-source.ss")

;;; random-triangular: random-source x real x real x real -> real
;;; random-triangular: real x real x real -> real
;;; This function returns a random variate from a triangular
;;; distribution with min, a, max, b, and mode, c.
(define random-triangular
  (case-lambda
    ((r a b c)
     (let ((u (unchecked-random-uniform r)))
       (if (<= u (/ (- c a) (- b a)))
           (+ a (sqrt (* u (- b a) (- c a))))
           (- b (sqrt (* (- 1.0 u) (- b a) (- b c)))))))
    ((a b c)
     (random-triangular (current-random-source) a b c))))

;;; triangular-pdf: real x real x real x real -> real
;;; This function computes the probability density p(x) at x of a
;;; triangular distribution with min, a, max, b, and mode, c.
(define (triangular-pdf x a b c)
  (if (< x a)
      ;; x < a
      0.0
      (if (<= x c)
          ;; a <= x <= c
          (/ (* 2.0 (- x a)) (* (- b a) (- c a)))
          (if (<= x b)
              ;; x <= x <= b
              (/ (* 2.0 (- b x)) (* (- b a) (- b c)))
              ;; x > b
              0))))

;;; triangular-cdf: real x real x real x real -> real
;;; This function computes the cummulative density d(x) at a for a
;;; triangular distribution with min, a, max, b, and mode, c.
(define (triangular-cdf x a b c)
  (if (< x a)
      0.0
      (if (<= x c)
          (/ (* (- x a) (- x a))
             (* (- b a) (- c a)))
          (if (<= x b)
              (- 1.0 (/ (* (- b x) (- b x))
                        (* (- b a) (- b c))))
              1.0))))